One of the new features of TMS WEB Core v1.9.7.0 was custom extensibility for Miletus applications. But what is that exactly? To put it simply, if you are after a native API we did not cover or you have custom routines you’d like to move separately you can take advantage of dynamic libraries and write your own extensions!

As the intro suggests a custom dynamic library will be needed. We’ve built in support for 4 different method types that can be used in dynamic libraries to execute them directly from a Miletus application. These are the following:

procedure MyProcedureWithParameter(AData: PChar); cdecl;
procedure MyProcedureWithoutParameter; cdecl;

function MyFunctionWithParameter(AData: PChar): PChar; cdecl;
function MyFunctionWithoutParameter: PChar; cdecl;

//Resolves with nil in case of await()
function ExecProc(ALibraryPath: string; AProc: string; AData: string): TJSPromise; 
function ExecProc(ALibraryPath: string; AProc: string): TJSPromise;

//Resolves with a string in case of await()
function ExecFunc(ALibraryPath: string; AFunc: string; AData: string): TJSPromise;
function ExecFunc(ALibraryPath: string; AFunc: string): TJSPromise;

It’s also possible to assign a callback that can be used to send custom messages to the Miletus application at any time. The only requirement for this is to implement RegisterCallback:

type
  TCallback = procedure(AMessageID: Integer; AData: PChar); cdecl;

var
  MyCallback: TCallBack;

const 
  MYID = 123;

procedure RegisterCallback(AFunction: Pointer); cdecl;
begin
  @MyCallback := AFunction;
end;

procedure MyProcedure; cdecl;
begin
  //Do something and call MyCallback
  MyCallback(MYID, '{"Name": "My data", "Value": "This is my JSON formatted data"}');
end;

In our small example we’ll take a look at how to expose the GetUserNameW Windows API to a Miletus application. Keep in mind this is for Windows only! If you want to extend your dynamic library to get the current username for macOS or Linux too, you’ll need to use/implement the OS specific calls for those platforms as well.

After creating a new dynamic library project in the Delphi IDE we’ll see an empty template. From here we only need to add one function that returns the result of GetUserName from the Winapi.Windows unit.

library DemoLib;

uses
  System.SysUtils,
  System.Classes,
  Winapi.Windows;

{$R *.res}

function GetCurrentUsername: PChar; cdecl;
var
  buf: array[0..255] of Char;
  bufsize: DWORD;
begin
  bufsize := SizeOf(buf);
  GetUserName(buf, bufsize);
  Result := buf;
end;

exports
  GetCurrentUsername;

begin
end.

As mentioned above we can call the methods directly from the dynamic library via promises. This means we’ll need to mark the TMiletusForm.OnCreate event implementation as [async], which allows us to await the results of our async calls.

[async]
procedure MiletusFormCreate(Sender: TObject);

Now we can use the TMiletusForm.OnCreate implementation to await the LoadLibrary and ExecFunc promises. LoadLibrary resolves with a Boolean value which indicates success of the library loading. ExecFunc resolves with a string that is the result from the DLL. And of course at the end we also free the library by calling UnloadLibrary. Putting this all together, we arrive at:

procedure TForm1.MiletusFormCreate(Sender: TObject);
var
  b: Boolean;
  user: string;
const
  LIBPATH = 'pathtoDemoLib.dll';
begin
  b := Await(Boolean, LoadLibrary(LIBPATH));
  if b then
  begin
    user := Await(string, ExecFunc(LIBPATH, 'GetCurrentUsername'));
    WebLabel1.Caption := 'Hello, ' + user + '!';
    UnloadLibrary(LIBPATH);
  end;
end;